defmodule SomethingErlangWeb.UserSessionController do
  use SomethingErlangWeb, :controller

  alias SomethingErlang.Accounts
  alias SomethingErlangWeb.UserAuth

  def create(conn, %{"_action" => "registered"} = params) do
    create(conn, params, "Account created successfully!")
  end

  def create(conn, %{"_action" => "password_updated"} = params) do
    conn
    |> put_session(:user_return_to, ~p"/users/settings")
    |> create(params, "Password updated successfully!")
  end

  def create(conn, params) do
    create(conn, params, "Welcome back!")
  end

  defp create(conn, %{"user" => user_params}, info) do
    %{"username" => username, "password" => password} = user_params

    if user = Accounts.login_sa_user_and_get_cookies(username, password) do
      conn
      |> put_flash(:info, info)
      |> put_session(:bbpassword, user.bbpassword)
      |> UserAuth.log_in_user(user, user_params)
    else
      conn
      |> put_flash(:error, "Login failed!")
      |> put_flash(:email, String.slice(username, 0, 160))
      |> redirect(to: ~p"/users/log_in")
    end
  end

  def delete(conn, _params) do
    conn
    |> put_flash(:info, "Logged out successfully.")
    |> UserAuth.log_out_user()
  end
end